概要

3D-render of partially-transparent Rhombic dodecahedron (dual of cuboctahedron Archimedean solid).

From en:Image:Rhombic dodecahedron.jpg

このダイアグラムの画像は、ベクターイメージである SVG ファイルとして再作成されるべきです。これにはいくつかの利点があります。詳しくはCommons:Media for cleanupを参照してください。この画像の SVG 形式がすでに利用可能である場合は、アップロードしてください。アップロード後、この画像にあるこのテンプレートを{{Vector version available|新しい画像ファイル名.svg}}テンプレートで置き換えてください。

この画像（あるいは、このカテゴリーやこのページにある全ての画像）は、JPEG形式でアップロードされました。 しかしながら、PNG形式、あるいはSVG形式で保存すれば、もっと効率的に、もっと正確に情報を含めることができます。もし可能であれば、JPEG圧縮を経ていないデータを元に、または現在のファイルにあるノイズを除去して、この画像を圧縮ノイズのないPNG形式またはSVG形式で再アップロードしてください。

ライセンス

この文書は、フリーソフトウェア財団発行のGNUフリー文書利用許諾書 (GNU Free Documentation License) 1.2またはそれ以降のバージョンの規約に基づき、複製や再配布、改変が許可されます。不可変更部分、表紙、背表紙はありません。このライセンスの複製は、GNUフリー文書利用許諾書という章に含まれています。http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	このファイルはクリエイティブ・コモンズ 表示-継承 3.0 非移植ライセンスのもとに利用を許諾されています。
	あなたは以下の条件に従う場合に限り、自由に 共有 – 本作品を複製、頒布、展示、実演できます。 再構成 – 二次的著作物を作成できます。 あなたの従うべき条件は以下の通りです。 表示 – あなたは適切なクレジットを表示し、ライセンスへのリンクを提供し、変更があったらその旨を示さなければなりません。これらは合理的であればどのような方法で行っても構いませんが、許諾者があなたやあなたの利用行為を支持していると示唆するような方法は除きます。 継承 – もしあなたがこの作品をリミックスしたり、改変したり、加工した場合には、あなたはあなたの貢献部分を元の作品とこれと同一または互換性があるライセンスの下に頒布しなければなりません。
	このライセンスのテンプレートは、GFDLのライセンス・アップデートによりこのファイルに追加されたものです。http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Povray code

The file was produced via the command "povray rhombic_dodecahedron.ini" on a Mac OS X machine with the fink installation of POV-Ray. The following three files are used. (GFDL applies to all)

File "rhombic_dodecahedron.povi"

#declare A=sqrt(2);
#declare R=0.025;

#declare rhombdod =
intersection {
    box { < -2, -2, -2>, <2,2,2> }
    plane { < 1, 1, 0>, A } 
    plane { < 1,-1, 0>, A }
    plane { <-1, 1, 0>, A }
    plane { <-1,-1, 0>, A }
    plane { < 1, 0, 1>, A }
    plane { < 1, 0,-1>, A }
    plane { <-1, 0, 1>, A }
    plane { <-1, 0,-1>, A }
    plane { < 0, 1, 1>, A }
    plane { < 0, 1,-1>, A }
    plane { < 0,-1, 1>, A }
    plane { < 0,-1,-1>, A }
    }

#declare tripod = 
    union{
        cylinder { <2,0,0>, <1,1,1>, R }
        cylinder { <0,2,0>, <1,1,1>, R }
        cylinder { <0,0,2>, <1,1,1>, R }
        sphere { <1,1,1>, R }
        }
#declare rhombdodedges =
    union {
        object { tripod }
        object { tripod rotate 90*z }
        object { tripod rotate 180*z }
        object { tripod rotate 270*z }
        object { tripod rotate 180*x }
        object { tripod rotate 180*x rotate 90*z }
        object { tripod rotate 180*x rotate 180*z }
        object { tripod rotate 180*x rotate 270*z }
        sphere { < 2, 0, 0 >, R }
        sphere { <-2, 0, 0 >, R }
        sphere { < 0, 2, 0 >, R }
        sphere { < 0,-2, 0 >, R }
        sphere { < 0, 0, 2 >, R }
        sphere { < 0, 0,-2 >, R }
        }

File "rhombic_dodecahedron.pov"

#include "colors.inc"
#include "rhombic_dodecahedron.povi"

global_settings{ ambient_light White }
background { color White }

#declare LX = 20;
#declare LZ = 50;
light_source { <LX,-LX,LZ> color White}
light_source { <-LX,LX,LZ> color White}
light_source { <LX,LX,LZ> color White}
light_source { <-LX,-LX,LZ> color White}

object { rhombdod
    texture {
        pigment { colour rgbt <1,1,0.4,0.3> }
        finish { ambient 0.1 diffuse 0.9 phong 1 }
        }
    }


object { rhombdodedges
    texture { pigment { colour Black } }
    }

camera {
    location 15*y
    direction -y
    right 0.3*x
    up 0.3*z
    rotate 10*x
    rotate 30*z
    }

File "rhombic_dodecahedron.ini"

Input_File_Name="rhombic_dodecahedron.pov"
Output_File_Type=N
Library_Path="/sw/share/povray-3.5/include/"
+v

+h256 +w256 Antialias=on